在從事使用powerbuilder進行數(shù)據(jù)庫開發(fā)的過程中,常常碰到要使用列表框來選擇數(shù)據(jù),但是普通的下拉列表框并沒有提供和數(shù)據(jù)相連接的方法,而使用數(shù)據(jù)窗口的子下拉列表框來代替又顯得有些別扭.下面介紹一種好看又好用的方法.
　　可能大家已經(jīng)想到了吧,使用指針把要連接的數(shù)據(jù)一條一條地從select 語句的查詢結果中fetch 出來,然后再把數(shù)據(jù)additem到下拉列表框中去.
　　雖然這也是一種可行的方法,但是他的速度很不能令人滿意,太受數(shù)據(jù)量的影響.
　　我們可以利用powerbuilder 最推崇的數(shù)據(jù)窗口技術作為數(shù)據(jù)庫和下拉列表框連接的橋梁,這種方法即方便快速又安全可靠.
好了,下面制作的下拉列表框,在完成之后會帶給你許多意想不到的方便!

一. 打開powerbuilder的"select user object"畫筆,選擇<new>, 在"new user object"中選擇"Visual"類的"Standard"項并按下<ok>, 在彈出來的"Select Standard Visual Type"對話框中選擇列表中的 "dropdownlistbox"項并按下<ok>. 接著加入一些實例變量,選擇"Declare"菜單項的"Instance Variables.."
加入變量的聲明: datastore ids_user int il_row 并按下<ok>.
我們要對新的對象進行一些限制,在對象的"constructor"事件中加入 程序:
sorted = false //這句非常必要
reset()

二. 好了,現(xiàn)在到了最關鍵的時候了,我們要把數(shù)據(jù)檢索出來放到ids_user
變量里.
選擇菜單"Declare"項的"User Object Function",在彈出來的對話框
中按下<new>新建一個對象函數(shù)命名為:
init
參數(shù)有一個:
sqlstr string
返回值為整型:integer
現(xiàn)在我們需要動態(tài)地創(chuàng)建datastore
在init函數(shù)中寫下:
//integer init(sqlstr string) 開始
long ll_rowcount
long ll_row
string ls_sql
string errors
string ls_return
ids_user = create datastore
//根據(jù)sql語句產(chǎn)生數(shù)據(jù)窗口
ls_return = sqlca.SyntaxFromSQL(sqlstr, 'style(type=grid)',errors)
//sql語句有錯誤
if len(errors) > 0 then
messagebox('錯誤', errors)
return -1
end if
//根據(jù)語法動態(tài)創(chuàng)建數(shù)據(jù)窗口
ids_user.create(ls_return)
ids_user.settransobject(sqlca)
ll_rowcount = ids_user.retrieve()
//無數(shù)據(jù)返回
if ll_rowcount=0 then
return -1
end if
//把數(shù)據(jù)插入控件
for ll_row = 1 to ll_rowcount
this.additem(string(ids_user.Object.Data[ll_row,1]))
next
//成功返回0
return 0
//integer init(sqlstr string) 結束

現(xiàn)在下拉列表框已經(jīng)能顯示數(shù)據(jù)了,但是我們在選擇數(shù)據(jù)的同時往往
需要的不是它顯示出來的值,比如顯示的是人員姓名,而我們需要的
是工號,難道再使用select語句把需要的數(shù)據(jù)檢索出來嗎?有了下面的
程序,我們就不必頭痛了.
重復上面建立函數(shù)的步驟,新建一個名為getdata的user object函數(shù),
返回值為"any"并在函數(shù)中寫下程序:
//any getdata() 開始
any la_return
long ll_row
if text = '' then
return ''
end if
//沒有選擇或沒有檢索到數(shù)據(jù)
if ids_user.rowcount() = 0 or il_row = 0 then
return ''
end if
//在缺省情況下返回第二列的數(shù)據(jù)
la_return = ids_user.Object.data[il_row, 2]
return la_return
//andy getdata() 結束

現(xiàn)在還不能返回正確的數(shù)據(jù),還需要一個函數(shù)setidx(idx int)
程序如下:
//setidx(idx int) 開始
il_row = idx
//setidx(idx int) 結束

現(xiàn)在這個user object已經(jīng)完成了,我們來做一下試驗試一試.
新建一個應用app_test,一個窗口w_main,按照剛才的方法創(chuàng)
建一個user object:uo_dbdropdownlistbox,放入w_main中
在app_test的open事件中寫下連接數(shù)據(jù)庫的語句并加上open(w_main)
在w_main的open事件中寫下:
int li_result
li_result = uo_1.init('select name, id from sysobjects')
在uo_1的selectionchanged事件中寫下:
setidx(index)
messagebox('提示', "看" + string(this.getdata()))
這時我們的用戶對象已經(jīng)能根據(jù)選擇的name返回相應的id了.
至于更多的功能,還有待powerbuilder的愛好者們不斷地思考
創(chuàng)造了.如果還想深入討論請和我聯(lián)系:fly-back@163.com