轉(zhuǎn)讓控制權(quán)，以便讓操作系統(tǒng)處理其它的事件。

DoEvents 函數(shù)會返回一個 Integer，以代表 Visual Basic 獨立版本中打開的窗體數(shù)目，例如，Visual Basic，專業(yè)版，在其它的應(yīng)用程序中，DoEvents 返回 0。

DoEvents 會將控制權(quán)傳給操作系統(tǒng)。當操作系統(tǒng)處理完隊列中的事件，并且在 SendKeys 隊列中的所有鍵也都已送出之后，返回控制權(quán)。

DoEvents 對于簡化諸如允許用戶取消一個已啟動的過程 — 例如搜尋一個文件 — 特別有用。對于長時間過程，放棄控制權(quán)最好使用定時器或通過委派任務(wù)給 ActiveX EXE 部件來完成。以后，任務(wù)還是完全獨立于應(yīng)用程序，多任務(wù)及時間片由操作系統(tǒng)來處理。

小心 確保以 DoEvents 放棄控制權(quán)的過程，在第一次 DoEvents 返回之前，不能再次被其他部分的代碼調(diào)用；否則會產(chǎn)生不可預(yù)料的結(jié)果。此外，如果其它的應(yīng)用程序可能會和本過程以不可預(yù)知的方式進行交互操作，那么也不要使用 DoEvents，因為此時不能放棄控制權(quán)。

使用 DoEvents

盡管 Timer 事件是后臺處理的最好工具，對耗時極多的任務(wù)，情況更是如此，但是，DoEvents 函數(shù)還是提供了一種取消任務(wù)的簡便方法。例如，下列代碼將顯示一個 "Process" 按鈕，單擊這個按鈕時，它將變成 "Cancel" 按鈕。再次單擊按鈕又將中斷正在執(zhí)行的任務(wù)。

'此按鈕標題是 "Process"
Private Sub Command1_Click()
'過程的所有實例都共享靜態(tài)變量。
  Static blnProcessing As Boolean
  Dim lngCt As Long
  Dim intYieldCt As Integer
  Dim dblDummy As Double
  '按下按鈕時，檢測是否在處理
  If blnProcessing Then
   '如果正在處理，則取消
      blnProcessing = False
  Else
      Command1.Caption = "Cancel"
      blnProcessing = True
      lngCt = 0
   '執(zhí)行一百萬次浮點乘法計算。每一千次后，檢測是否要取消。
      Do While blnProcessing And (lngCt < 1000000)
        For intYieldCt = 1 To 1000
            lngCt = lngCt + 1
            dblDummy = lngCt * 3.14159
        Next intYieldCt
      'DoEvents 語句允許其它事件發(fā)生，包括第二次按此按鈕。
        DoEvents
      Loop
      blnProcessing = False
      Command1.Caption = "Process"
      MsgBox lngCt & " multiplications were performed"
  End If
End Sub

DoEvents 將控制切換到操作環(huán)境內(nèi)核。只要此環(huán)境中的所有應(yīng)用程序都有機會響應(yīng)待處理事件，應(yīng)用程序就又恢復(fù)控制。這不會使應(yīng)用程序放棄焦點，但會使后臺事件能夠得到處理。

這種妥協(xié)的結(jié)果可能并不總是達到預(yù)期目標。例如，下述 Click 事件代碼在單擊按鈕后要一直等候十秒鐘，而后才顯示一條信息。如果在按鈕正在等待期間單擊它，則將以相反順序完成單擊操作。

Private Sub Command2_Click()
  Static intClick As Integer
  Dim intClickNumber As Integer
  Dim dblEndTime As Double
      '每次單擊按鈕時
      '賦予唯一數(shù)值。
  intClick = intClick + 1
  intClickNumber = intClick
      '等待十秒。
  dblEndTime = Timer + 10#
  Do While dblEndTime > Timer
      '不做任何事情，僅僅允許
      '其它應(yīng)用程序處理
      '它們的事件。
      DoEvents
  Loop
  MsgBox "Click " & intClickNumber & " is finished"
End Sub

對于通過 DoEvents 放棄控制的事件過程，有時可能希望防止在 DoEvents 返回之前重新調(diào)用這一過程。否則將無窮無盡地調(diào)用該過程，直到系統(tǒng)資源消耗殆盡。可暫時禁止控件，或象上例一樣，使用一個靜態(tài)的“標志”變量防止此事發(fā)生。

在使用全局數(shù)據(jù)時避免 DoEvents
當一個函數(shù)已通過 DoEvents 放棄控制時，可相當安全地再次調(diào)用函數(shù)。例如，下一過程將檢測質(zhì)數(shù)并用 DoEvents 語句周期地啟動其它應(yīng)用程序處理事件：

Function PrimeStatus (TestVal As Long) As Integer
  Dim Lim As Integer
  PrimeStatus = True
  Lim = Sqr(TestVal)
  For I = 2 To Lim
      If TestVal Mod I = 0 Then
        PrimeStatus = False
        Exit For
      End If
      If I Mod 200 = 0 Then DoEvents
  Next I
End Function

該代碼中每重復(fù) 200 次就調(diào)用一次 DoEvents 語句。這樣一來，當該環(huán)境的其余部分對事件作出響應(yīng)時，只要有必要，PrimeStatus 過程就可繼續(xù)計算。

考慮在調(diào)用 DoEvents 期間發(fā)生的事情。在其它窗體和應(yīng)用程序處理事件時將暫停執(zhí)行應(yīng)用程序代碼。這些事件之一有可能是一個按鈕單擊操作，它將再次啟動 PrimeStatus 過程。

這將導(dǎo)致重新進入 PrimeStatus 過程的，但是，因為在函數(shù)每次出現(xiàn)時，堆棧都為其參數(shù)和局部變量分配了空間，所以重入不會引發(fā)沖突。當然，如果過多調(diào)用 PrimeStatus，則可能出現(xiàn)“溢出堆�？臻g”錯誤。

如果 PrimeStatus 使用或改變模塊級變量或全局數(shù)據(jù)，情況就會完全不同。此時，在 DoEvents 能夠返回之前執(zhí)行 PrimeStatus 的另一個實例，這將導(dǎo)致模塊數(shù)據(jù)或全局數(shù)據(jù)的值完全不同于它們在調(diào)用 DoEvents 之前的值。于是，PrimeStatus 的結(jié)果將會難以預(yù)料。


       以上代碼來自： 源代碼數(shù)據(jù)庫(SourceDataBase)
           當前版本： 1.0.392
               作者： Shawls
           個人主頁： Http://Shawls.Yeah.Net
             E-Mail： ShawFile@163.Net
                 QQ： 9181729