作者:superhackerlin
E-mail:happyhunterlin@21cn.com

大家都知道,函數(shù)SetForegroundWindow用于切換前臺(tái)窗口,但事實(shí)上它往往并未達(dá)到
我們想要的目的:SetForegroundWindow并不能用于和其他進(jìn)程的窗口協(xié)同工作,通常
情況下SetForegroundWindow會(huì)調(diào)用FlashWindowEx來閃爍目標(biāo)窗口,代表已經(jīng)切換了
窗口,但事實(shí)上往往我們需要在某個(gè)時(shí)候?qū)⑽覀兊拇翱趶棾龅阶钋芭_(tái)來!曾聽說過有高
手使用修改窗口切換的糸統(tǒng)規(guī)則來達(dá)到此目的,這樣做未必太麻煩了,必定不是每個(gè)人
都是高手呢!下面給大家介紹一個(gè)"偏方",非常簡單,只是利用了一個(gè)MSDN未公開的函數(shù)罷了.
好,come on ,follow me!

這個(gè)未公開的函數(shù)是:SwitchToThisWindow
它的c格式的原形是:
void WINAPI SwitchToThisWindow (
                  HWND hWnd,   // Handle to the window that should be activated
                  BOOL bRestore // FAULS表示最小化顯示;
                  );

由于沒有原型和庫,我們在使用時(shí)通常用動(dòng)態(tài)聯(lián)接法：
szUser32 db "user32.dll",0
szFuName db "SwitchToThisWindow",0
...

invoke   GetModuleHandle,addr szUser32 ;得到地址空間內(nèi)user32.dll的模塊句柄；
mov  　　hUser32,eax

invoke   GetProcAddress,hUser32,addr szFuName ;得到SwitchToThisWindow的地址;
mov  FuAddr,eax

當(dāng)想把窗口彈到最前臺(tái)來時(shí)可以用如下語句:

push  TRUE
push  hWnd  ;窗口句柄
call  FuAddr

下面是我寫的一個(gè)例子程序,此程序會(huì)每隔五秒鐘就彈到最前臺(tái)來.此程序只在winxp下通過測試,
如在其他糸統(tǒng)下有問題的話請通知我!

.386
.model flat,stdcall
option casemap:none
include windows.inc
include gdi32.inc
includelib gdi32.lib
include user32.inc
includelib user32.lib
include kernel32.inc
includelib kernel32.lib

.data?
FuAddr      dd    ?
hUser32     dd    ?
hInstance dd ?
hWinMain    dd ?

.const
szClassName    db 'MyClass',0
szCaptionMain db '前臺(tái)窗口',0
szText    db '前臺(tái)窗口切換演示',0
szUser32       db "user32.DLL",0             
szFuName       db   "SwitchToThisWindow",0      

.code
_ProcWinMain proc uses ebx edi esi,hWnd,uMsg,wParam,lParam
local @stPs:PAINTSTRUCT
local @stRect:RECT
local @hDc

mov eax,uMsg

.if eax == WM_PAINT
invoke BeginPaint,hWnd,addr @stPs
mov @hDc,eax
invoke GetClientRect,hWnd,addr @stRect
invoke DrawText,@hDc,addr szText,-1,addr @stRect,\
DT_SINGLELINE or DT_CENTER or DT_VCENTER
invoke EndPaint,hWnd,addr @stPs
.elseif eax == WM_CLOSE
invoke DestroyWindow,hWinMain
invoke PostQuitMessage,NULL
        .elseif eax == WM_TIMER   ;注意此處調(diào)用SwitchToThisWindow!
                push  TRUE
                push  hWnd
                call  FuAddr
        .else
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
        .endif
xor eax,eax
ret
_ProcWinMain endp

_WinMain proc
local @stWndClass:WNDCLASSEX
local @stMsg:MSG
  invoke GetModuleHandle,NULL
mov hInstance,eax
        invoke   GetModuleHandle,addr szUser32    ;得到地址空間內(nèi)user32.dll的模塊句柄；
        mov   hUser32,eax
        invoke   GetProcAddress,hUser32,addr szFuName   ;得到SwitchToThisWindow的地址;
        mov   FuAddr,eax
invoke RtlZeroMemory,addr @stWndClass,sizeof @stWndClass
invoke LoadCursor,0,IDC_ARROW
mov @stWndClass.hCursor,eax
push hInstance
pop @stWndClass.hInstance
mov @stWndClass.cbSize,sizeof WNDCLASSEX
mov @stWndClass.style,CS_HREDRAW or CS_VREDRAW
mov @stWndClass.lpfnWndProc,offset _ProcWinMain
mov @stWndClass.hbrBackground,COLOR_WINDOW + 1
mov @stWndClass.lpszClassName,offset szClassName
invoke RegisterClassEx,addr @stWndClass

invoke CreateWindowEx,WS_EX_CLIENTEDGE,offset szClassName,offset szCaptionMain,\
WS_OVERLAPPEDWINDOW,150,150,600,400,NULL,NULL,hInstance,NULL
mov hWinMain,eax
invoke ShowWindow,hWinMain,SW_SHOWNORMAL
invoke UpdateWindow,hWinMain
        invoke  SetTimer,hWinMain,1,5000,NULL       ;設(shè)置一個(gè)計(jì)時(shí)器,每五秒鐘調(diào)用一次

.while TRUE
invoke GetMessage,addr @stMsg,NULL,0,0
.break .if eax == 0
invoke TranslateMessage,addr @stMsg
invoke DispatchMessage,addr @stMsg
.endw
ret
_WinMain endp

start:
call _WinMain
invoke ExitProcess,NULL
end start