陳旭波

“郵件特快專遞”這個(gè)詞現(xiàn)在已經(jīng)是被廣大的網(wǎng)民所熟知了，它就好比是網(wǎng)絡(luò)上的EMS，能夠直接把郵件送到對(duì)方的郵箱中，郵件發(fā)送完畢后，對(duì)方就可以立刻收到。Foxmail在其最新的4.0版本中也特別新增了該功能，作為一名編程愛好者，你是不是也想知道如何編程實(shí)現(xiàn)該功能呢？那就隨本文一起揭開“郵件特快專遞”的神秘面紗：
一、實(shí)現(xiàn)原理
在Outlook Express中，可通過查看郵件的屬性得到該郵件的頭部資料。我們拿一封不是特快專遞的普通郵件來進(jìn)行剖析，下面是筆者一封郵件的頭部資料：

Received: from sm1.163.com([202.108.44.203]) by peoplemail.com.cn(JetMail 2.5.3.0)
with SMTP id jm1ac3c063eec; Thu, 29 Nov 2001 07:20:25 -0000
Received: from xubo (unknown [61.154.94.146])
by sm1.163.com (Postfix) with ESMTP id 99CF11C461061
for ; Thu, 29 Nov 2001 15:12:49 +0800 (CST)
……
從該頭部資料可以看出，郵件傳遞的路線是由xubo→sm1.163.com→peoplemail.com.cn，其中xubo是本人所在機(jī)器，郵件是經(jīng)由sm1.163.com這個(gè)中轉(zhuǎn)站才送到目的地的，而我們平常所說的郵件特快專遞，就是把郵件直接送到目的地而不需要中轉(zhuǎn)站。
如何才能知道目的地的地址呢？我們知道電子郵件的地址由用戶名(username)和郵箱域名（address.com）兩部分構(gòu)成的，給域名服務(wù)器發(fā)送針對(duì)“address.com”的MX指令查詢即可找到目的地的地址。被查出來的目的地可能不止一個(gè)，有時(shí)這些目的地是有優(yōu)先級(jí)別之分的，分別對(duì)應(yīng)著郵件的優(yōu)先級(jí)別，你可以根據(jù)郵件優(yōu)先級(jí)的不同對(duì)應(yīng)發(fā)送，也可以任意選擇其中一個(gè)發(fā)送，本文的示例將選擇反饋回來的第一個(gè)目的地發(fā)送，讀者可根據(jù)實(shí)際需要進(jìn)行改進(jìn)。

二、用到的核心組件
本文將采用Indy控件集進(jìn)行域名查詢、郵件發(fā)送部分的編程。INDY的全名是Internet Direct（也叫Winshoes），是一套開放源代碼、跨平臺(tái)、優(yōu)秀的Internet控件集，它支持大部分流行的Internet協(xié)議。Delphi 6已經(jīng)包含了該控件集，如果你使用的是Delphi 6以前的版本，請(qǐng)先到Indy主頁http://www.nevrona.com/Indy/Download.html下載并安裝該控件集。

三、窗口設(shè)計(jì)
向窗體上放置三個(gè)TEdit組件，一個(gè)TMemo組件，四個(gè)Tlabel組件，用到的Indy組件為TIdDNSResolver、TIdAntiFreeze、TIdSMTP、TIdMessage。其中TIdDNSResolver是用來向域名服務(wù)器發(fā)出查詢請(qǐng)求并得到結(jié)果，TIdMessage用來構(gòu)建郵件，TIdSMTP用來發(fā)送郵件，TidAntiFreeze可以確保Indy在工作時(shí)程序能響應(yīng)來自外界的消息(注：Indy是以同步的方式進(jìn)行工作的，在讀或?qū)懖僮魍瓿芍�前，其它代碼無法執(zhí)行，加入TidAntiFreeze可以在每隔一段時(shí)間通過呼叫Application.ProcessMessage方法響應(yīng)來自外界的消息。)
程序的界面如下圖所示(箭頭所指向的文字標(biāo)識(shí)了該組件的名字)：

四、程序代碼(代碼中包含了詳細(xì)的說明)

……(前面一部分省略)
type
TForm1 = class(TForm)
IdDNSResolver: TIdDNSResolver;
IdAntiFreeze1: TIdAntiFreeze;
btnSend: TButton;
IdSMTP: TIdSMTP;
IdMsgSend: TIdMessage;
mmContent: TMemo;
Label1: TLabel;
edtTo: TEdit;
Label4: TLabel;
Label5: TLabel;
edtFrom: TEdit;
Label6: TLabel;
edtSubject: TEdit;
procedure btnSendClick(Sender: TObject);
private
{ Private declarations }
procedure GetMxList(AMxList: TStringList; AQName: string);
public
{ Public declarations }
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

{ 這個(gè)過程是用來得到郵件特快專遞目的地服務(wù)器名稱及優(yōu)先級(jí)別數(shù)，參數(shù)AMXList是
用來接收結(jié)果值，AQName代表傳遞過來的域名 }
procedure TForm1.GetMxList(AMxList: TStringList; AQName: string);
var
i: Integer;
begin
with IdDNSResolver do
begin
Host := '202.101.107.55'; { Host屬性用來指定域名服務(wù)器的地址，此處為筆者所在地
的主域名服務(wù)器地址，你也可以指定任一可以快速訪問到的Internet上域名服務(wù)器
地址，要知道自己所在地的域名服務(wù)器地址，win98下通過winipcfg命令,win2000下
通過ipconfig /all即可查出。}
ReceiveTimeout := 10000; // 在指定的時(shí)間內(nèi)得不到域名服務(wù)器的反饋，則視為失敗。
ClearVars; // 清除前一次查詢所反饋回來的資源記錄

{ 構(gòu)建此次查詢的頭部結(jié)構(gòu) }
with DNSHeader do
begin
Qr := False; // False 代表查詢
Opcode := 0; // 0代表標(biāo)準(zhǔn)域名查詢
RD := True; //域名服務(wù)器可以進(jìn)行遞歸查詢
QDCount := 1; //查詢的數(shù)量
end;

{ 構(gòu)建要查詢的問題 }
DNSQDList.Clear;
with DNSQDList.Add do
begin
QName := AQName; //要查詢的域名
QType := cMX; //QTYPE指定要查詢的資源記錄的種類，值為cMX代表郵件交換記錄
QClass := cIN;
end;

ResolveDNS; //向域名服務(wù)器發(fā)出請(qǐng)求

{ 從域名服務(wù)器接收反饋的結(jié)果，將反饋回來的郵件服務(wù)器名稱放在AMXList列表的Name部分，
郵件服務(wù)器的優(yōu)先級(jí)別數(shù)放在Value部分。 }
for i := 0 to DNSAnList.Count - 1 do
AMxList.Add(DNSAnList[i].RData.MX.Exchange + '=' +
IntToStr(DNSAnList[i].RData.MX.Preference));
end;
end;

{ 單擊"發(fā)送"按鈕時(shí)發(fā)送專遞郵件 }
procedure TForm1.btnSendClick(Sender: TObject);
var
MxList: TStringList;
i: Integer;
QName, ThoughAddress: string;
begin
{ 根據(jù)用戶所填寫的內(nèi)容創(chuàng)建郵件 }
with IdMsgSend do
begin
Body.Assign(mmContent.Lines); //郵件正文
From.Address := Trim(edtFrom.Text); //發(fā)件人地址
Recipients.EMailAddresses := Trim(edtTo.Text); //收件人地址
Subject := edtSubject.Text; //郵件主題
end;

{ 從輸入的收件人地址中取出郵箱域名，利用前面的GetMxList過程得到目的地地址 }
QName := TrimRight(copy(edtTo.Text, Pos('@', edtTo.Text) + 1, Length(edtTo.Text)));
MxList := TStringList.Create;
try
GetMxList(MxList, QName);
ThoughAddress := MxList.Names[0]; {取反饋回來的第一個(gè)服務(wù)器為目的地，讀者可
根據(jù)實(shí)際需要改進(jìn)，比如說考慮到信件的優(yōu)先級(jí)或當(dāng)你選擇的服務(wù)器因繁忙而暫時(shí)
不能處理你的信件時(shí)，換用其它服務(wù)器試試 }
finally
MxList.Free;
end;

{ 發(fā)送郵件 }
with IdSMTP do
begin
Host := ThoughAddress; // 將Host賦值為目的地，這就是特快專遞與普通郵件的區(qū)別
Port := 25; // smtp服務(wù)默認(rèn)的端口為25
Connect; //連接到服務(wù)器
try
Send(IdMsgSend); //發(fā)送剛才創(chuàng)建的郵件
ShowMessage('發(fā)送完畢'); //發(fā)送完畢后提示
finally
Disconnect; //斷開服務(wù)器連接
end;
end;
end;

end.

本程序在Windows 2000 + Delphi 6 下調(diào)試通過。